ORACLE的存储过程的异步调用-技术开发专区

ORACLE的存储过程的异步调用

作者：王辉编辑：魏国亮 2006-06-27 20:25

【IT168 技术文档】在oracle数据库实际应用过程中，经常把业务处理逻辑的放在存储过程，客户端通过ado进行调用。有些业务逻辑处理量大并且复杂，使客户端调用存储过程后，长时间没有反应，也不知存储过程运行状态，本文讲述如何在oracle通过任务和管道的应用，异步调用存储过程的方法。

1. 基本原理

1.使用DBMS_JOB包将主处理存储过程作为任务提交到任务队列中

2.主处理存储过程在运行过程中通过DBMS_PIPE包将处理情况放在管道中

3.监控存储过程读取管道，从而了解处理情况

4.本文没有描述双向通信的方式，监控存储过程可以通过管道发送信息给主处理存储过程

2. 具体实现测试

建立测试环境

2.1. 对数据库的ini进行相关修改，使系统的任务队列功能打开

对于ORACLE9I，只需修设定数据库的INI内的"JOB_QUEUE_PROCESSES=非0值"，如"JOB_QUEUE_PROCESSES=10"，对于ORACLE8I除设定实例ini文件中的"JOB_QUEUE_PROCESSES=非0值"外，还需设定"job_queue_interval=1"

2.2. 设用用户权限

由于使用ORACLE中特定的程序包，所以要注意要明文给于用户系统权限。对当前用户（测试用户），赋于以下权力

    EXECUTE DBMS_PIPE
    EXECUTE DBMS_LOCK
    EXECUTE DBMS_JOB

2.3. 建立模拟大业务处理存储过程

本存储过程通过循环30次，调用DBMS_LOCK.SLEEP(1)（体眠1秒）和写管道模拟大的处理过程。

具体代码如下：

CREATE OR REPLACE PROCEDURE maxpro AS
n integer;
status NUMBER;
BEGIN
FOR N IN 1..30 LOOP
DBMS_PIPE.PURGE('maxpro'); --清除原管道信息
DBMS_PIPE.PACK_MESSAGE(N); --把信息放入缓冲区
status:=DBMS_PIPE.SEND_MESSAGE('maxpro');
DBMS_LOCK.SLEEP(1);
END LOOP;
DBMS_PIPE.PURGE('maxpro'); --清除原管道信息
DBMS_PIPE.PACK_MESSAGE(999999); --把信息放入缓冲区,用999999 表示过程完成
status:=DBMS_PIPE.SEND_MESSAGE('maxpro');
END maxpro;

2.4. 建立读取管道动态了解处理状态的存储过程

以下代码是对于maxpro存储过程的状态进行读取的过程，主要使用读取管道的方法，注意：

status:= DBMS_PIPE.RECEIVE_MESSAGE('maxpro',0);

中的"0"参数是很关键的，说明接受等待时间为0秒，表示,调用时如果没有信息不等待直接返回。

具体代码如下：

CREATE OR REPLACE PROCEDURE readmaxpro AS
n integer;
status integer;
begin
--接受等待时间为1秒,可以为0,立即调用或DBMS_PIPE.RECEIVE_MESSAGE('mypipe') 等待100天
status:= DBMS_PIPE.RECEIVE_MESSAGE('maxpro',0);
--status为0为成功可以UNPACK_MESSAGE，1为超时没有数据，2为信息太大，3为内部错误
IF status <> 0 THEN
DBMS_OUTPUT.PUT_LINE('管道中现在没有信息返回');
return;
END IF;
DBMS_PIPE.UNPACK_MESSAGE(n);
DBMS_OUTPUT.PUT_LINE('maxpro 的当前进行状态为'|| n);
end;

2.5. -起动模拟大业务处理存储过程为后台进程的存储过程（BEGINMAXPRO）

通过DBMS_JOB.SUBMIT(JOB,'maxpro;',sysdate,NULL,FALSE);使"maxpro"为一个任务，在当前时间（sysdate）后执行,当然如果把sysdate改一具体时间，那就在具体时间执行

具休代码如下：

CREATE OR REPLACE PROCEDURE beginmaxpro AS
JOB BINARY_INTEGER;
BEGIN
DBMS_JOB.SUBMIT(JOB,'maxpro;',sysdate,NULL,FALSE);
DBMS_OUTPUT.PUT_LINE('队列号码JOB=' || JOB);
COMMIT;
end;

3. 代码执行

3.1. 执行过程

注：黑体字是屏幕输出
在CMD行输入 sqlplus 根据提示登录
设定DBMS_OUTPUT可见
SQL> set serveroutput ON
以下是执行过程和相应的返回信息
SQL> call beginmaxpro();
队列号码JOB=21
调用完成。
SQL> call readmaxpro();
maxpro 的当前进行状态为14
调用完成。
SQL> call readmaxpro();
maxpro 的当前进行状态为16
调用完成。
SQL> call readmaxpro();
maxpro 的当前进行状态为23
调用完成。
SQL> call readmaxpro();
maxpro 的当前进行状态为999999
调用完成。
SQL> call readmaxpro();
管道中现在没有信息返回
调用完成。
SQL>

3.2. 执行分析

beginmaxpro()，将主处理存储过程放入队列的过程，执行后存储程序马上返回，maxpro存储过程放在任务队列中，并设定为在当前系统时间执行（马上执行）

maxpro为主处理存储过程，开始执行模拟大业务处理，处理过程中将处理进度信息写入管道

readmaxpro();为检查状态存储过程，首先读取信息，如果信息不存在，说明管道内没有信息可读而退出；如果存在信息则读出信息

本例子可以进行改进，输出不通过DBMS_OUTPUT.PUT_LINE而是用返回值，那么就可以在前端用ADO调用，发布任务，任务过程中从客户端读取进度。代码如下：

CREATE OR REPLACE PROCEDURE readmaxpro(p out intergr) AS
n integer;
status integer;
begin
status:= DBMS_PIPE.RECEIVE_MESSAGE('maxpro',0);
IF status <> 0 THEN
P:=-1;
return;
END IF;
DBMS_PIPE.UNPACK_MESSAGE(p);
end;

4. 附录：

4.1. 相关程序包说明

DBMS_JOB.SUBMIT(
JOB OUT BINARY_INTEGER,
WHAT IN VARCHAR2,
NEXT_DATE IN DATE DEFAULTSYSDATE,
INTERVAL IN VARCHAR2 DEFAULT 'NULL',
NO_PARSE IN BOOLEAN DEFAULT FALSE,
INSTANCE IN BINARY_INTEGER DEFAULT ANY_INSTANCE,
FORCE IN BOOLEAN DEFAULT FALSE)

    功能：提交作业入作业队列
    参数说明：
    JOB:作业的作业号，输出参数
    WHAT：作业对应的PL/SQL代码（一般用于过程名)
    NEXT_DATE:下一次作业运行的时间
    INTERVAL:作业执行间隔时间，缺省是NULL,只执行一次
    NO_PARSE:是否对WHAT语句，在提交时进行分析，缺省是进行分析。
    INSTANCE：作业提交时，指明运行作业的实例，缺省是0，任何的数据库全可以
    FORCE：是否检查INSTANCE指定的数据库在运行，缺省是FALSE，不检查
    例子：

declare
jobn number;
begin
DBMS_JOB.SUBMIT(jobn,'maxpro;',sysdate);
DBMS_OUTPUT.PUT_LINE('JOB=' || jobn);
COMMIT;
end;

注意：

设定数据库参数JOB_QUEUE_PROCESSES = 非0值（最大队列数最大60）

对于9I前设定数据库参数JOB_QUEUE_INTERVAL = 非0值（队列扫描周期1-3600秒）

4.2

DBMS_PIPE.PACK_MESSAGE (item IN VARCHAR2);
DBMS_PIPE.PACK_MESSAGE (item IN NCHAR);
DBMS_PIPE.PACK_MESSAGE (item IN NUMBER);
DBMS_PIPE.PACK_MESSAGE (item IN DATE);
DBMS_PIPE.PACK_MESSAGE_RAW (item IN RAW);
DBMS_PIPE.PACK_MESSAGE_ROWID (item IN ROWID);

功能：把一个数据项放到私有数据缓冲区

4.3

DBMS_PIPE.SEND_MESSAGE (
pipename IN VARCHAR2,
timeout IN INTEGER DEFAULT MAXWAIT,
maxpipesize IN INTEGER DEFAULT 8192)
RETURN INTEGER;

功能：发送私有数据缓冲区的信息到命名管道，如果管道不存在就建立

4.4

DBMS_PIPE.RECEIVE_MESSAGE (
pipename IN VARCHAR2,
timeout IN INTEGER DEFAULT maxwait) RETURN INTEGER;

功能：从管道到接受信息放到数据缓冲区

4.5

DBMS_PIPE.UNPACK_MESSAGE (item OUT VARCHAR2);
DBMS_PIPE.UNPACK_MESSAGE (item OUT NCHAR);
DBMS_PIPE.UNPACK_MESSAGE (item OUT NUMBER);
DBMS_PIPE.UNPACK_MESSAGE (item OUT DATE);
DBMS_PIPE.UNPACK_MESSAGE_RAW (item OUT RAW);
DBMS_PIPE.UNPACK_MESSAGE_ROWID (item OUT ROWID);

功能：从数据缓冲区接收下一个数据项

4.6

DBMS_PIPE.PURGE ( pipename IN VARCHAR2);

功能：清除管道内的信息

关注我们