替文件夹加上“从此处开始运行测试服务器”的菜单-技术开发专区

替文件夹加上“从此处开始运行测试服务器”的菜单

作者：ITPUB论坛编辑： nancy 2008-05-04 00:00

【IT168技术文档】

VS2005/2008(.NET 2.0) 本身自带了一个 WebDevServer，所以开发调试简单了很多，至少不需要去折腾IIS了。
平时从网上下载很多Demo的时候需要一个测试服务器，就可以用它来完成，也比用IIS省事许多。

这个测试服务器位于 %systemroot%\Microsoft.NET\Framework\v2.0.50727\WebDev.WebServer.EXE，是命令行操作的，参数如下：

WebDev.WebServer /port:<端口号> /path:<程序所在目录> [/vpath:<虚拟路径，可选，默认挂载到根目录>]

但是私下里感觉用命令行操作太过麻烦，所以这次来在文件夹上面添加一个右键菜单：

考虑到要删除和自定义端口什么的参数，所以写成一个批处理文件：

@ECHO OFF
TITLE .NET 开发测试服务器文件夹扩展
IF NOT EXIST %systemroot%\Microsoft.NET\Framework\v2.0.50727\WebDev.WebServer.EXE (
ECHO 很抱歉，未在您的系统上检测到 .NET Framework 2.0，无法使用测试服务器。
ECHO 按任意键退出。。
PAUSE >nul
EXIT
)
ECHO 请选择要进行的操作：
ECHO -------------------------------------------------------------
ECHO 1. 安装菜单扩展
ECHO 2. 删除菜单扩展
ECHO 3. 退出
ECHO.
CHOICE /C 123 /M 请输入你的选择
ECHO.
ECHO.
ECHO.
IF ERRORLEVEL 3 EXIT
IF ERRORLEVEL 2 GOTO DELETEEXT
IF ERRORLEVEL 1 GOTO INSTALLEXT
EXIT
:DELETEEXT
REG DELETE HKCR\Folder\shell\devserver /y 1>nul 2>nul
ECHO 菜单扩展已经成功删除！按任意键退出
PAUSE >nul 2>nul
EXIT
:INSTALLEXT
CLS
TITLE 安装 .NET 开发测试服务器文件夹扩展
ECHO 安装 .NET 开发测试服务器文件夹扩展
ECHO -------------------------------------------------------------
ECHO.
ECHO 配置菜单扩展的服务器参数，这里配置的端口、虚拟路径在以后
ECHO 启动测试服务器的时候，将会使用这里配置的参数运行（
ECHO.
ECHO.
set port=80
set vpath=/
set /p port=请输入测试的端口号(默认是80，直接按回车采纳默认值):
set /p vpath=请输入虚拟目录路径(默认是根目录/，直接按回车采纳默认值):
ECHO.
ECHO.
ECHO 正在写入注册表……
REG ADD HKCR\Folder\shell\devserver /f
REG ADD HKCR\Folder\shell\devserver /f /v "" /t REG_SZ /d "基于此目录运行测试服务器 (.NET 2.0)"
REG ADD HKCR\Folder\shell\devserver\command /f
REG ADD HKCR\Folder\shell\devserver\command /f /v "" /t REG_SZ /d "%systemroot%\Microsoft.NET\Framework\v2.0.50727\WebDev.WebServer.EXE /port:%port% /path:\"%%1\" /vpath:\"%vpath%\"
ECHO 完成
ECHO.
ECHO.
ECHO.
ECHO -------------------------------------------------------------
ECHO Script by 随风飘扬(fly_woodenfish@163.com),2008年4月17日
PAUSE >nul
EXIT

关注我们