【IT168技术文档】Java服务器端程序的部署问题一直让人比较头痛，特别是was6，安装一个复杂的ear包有很多配置工作需要做，不仅复杂而且散步在很多环节当中，即使是一线开发人员也很容易出错或者遗漏，交付给测试和部署人员则更是问题不断，即使连篇累牍的编写部署手册也很难取得一个比较好的效果。经过很多评估工作之后，我们决定采用was自带的命令行工具(websphere/appserver/profiles/appserver01/bin/wsadmin)，编写jacl脚本，集成到ant中，利用ant强大的项目构建能力，简化测试、部署工作。下面的描述都是以我们自身项目为例。

    做为一个典型的java企业应用，我们在部署阶段要做的事情有：
1.定义一个J2C认证
2.配置一个Oracle 10g数据源
3.配置一个WebSphere MQ队列连接工厂
4.配置多个WebSphere MQ Queue队列
5.配置多个侦听器端口
6.安装多个EAR包

    以上每一个步骤都可以当作一个脚本的一部分来执行，但是为了讲述方便，我们将把不同的脚本分开描述、分开执行。脚本可以任意命名，但是因为我们使用jacl来编写的，所以我们还是遵循了*.jacl的规则，jacl脚本是一个很类似于tcl语言的东西。执行这些脚本有一个统一的方法：%WAS install%\profiles\appserver01\bin wsadmin –f test.jacl 。appserver01只是我们自己的server名称，请大家自行对照自己的was配置。test.jacl是脚本文件的名称。

首先建立J2C认证，脚本j2c.jacl:

#执行要配置的cell
set myCell zxhNode01Cell
set security [$AdminConfig getid /Cell:$myCell /Security:/]
$AdminConfig required JAASAuthData
#认证别名
set alias [list alias dcmp2]
#用户id
set userid [list userId dcmp2]
#密码
set password [list password dcmp2]
set jaasAttrs [list $alias $userid $password]
$AdminConfig create JAASAuthData $security $jaasAttrs
$AdminConfig save

    执行该脚本将创建一个别名、帐号、密码均为dcmp2的j2c认证，该认证会被后面的数据源使用。

    现在建立Oracle 10g数据源，脚本dbpool.jacl:

#指定cell
set myCell zxhNode01Cell
#指定要配置的node
set myNode zxhNode01
set node [$AdminConfig getid /Cell:$myCell /Node:$myNode /]
#创建jdbc provider
$AdminConfig attributes JDBCProvider
set implementationClassName [list implementationClassName oracle.jdbc.pool.OracleConnectionPoolDataSource]
#jdbc provider的名称
set name [list name Oracle10g]
set classpath [list classpath E:/DCMP2.0/lib/OracleDriver/ojdbc14_10.jar]
set jdbcAttrs [list $name $implementationClassName $classpath]
$AdminConfig create JDBCProvider $node $jdbcAttrs
$AdminConfig save
#创建DataSource
set jdbc [$AdminConfig getid /Cell:$myCell /Node:$myNode/JDBCProvider:Oracle10g/]
$AdminConfig attributes DataSource
set jndi [list jndiName jdbc/dcmp2]
set name [list name dcmp2]
set dsAttrs [list $jndi $name]
set newds [$AdminConfig create DataSource $jdbc $dsAttrs]
$AdminConfig save
#指定数据库url
set url [list [list name URL] [list value jdbc:oracle:thin:@127.0.0.1:1521:workdb] [list type java.lang.String]]
#指定连接池的db helper类
set helper [list datasourceHelperClassname com.ibm.websphere.rsadapter.Oracle10gDataStoreHelper]
#认证别名
set xauthDataAlias_attr [list authDataAlias dcmp2]
set xnewprops [list $url]
set xresprops [list resourceProperties $xnewprops]
set xps_attr [list propertySet [list $xresprops]]
set xattrs [list $helper $xauthDataAlias_attr $xps_attr]
$AdminConfig modify $newds $xattrs
$AdminConfig save
#配置连接池
$AdminConfig attributes ConnectionPool
set maxConnections [list maxConnections 40]
set minConnections [list minConnections 10]
set unusedTimeout [list unusedTimeout 60]
set poolAttrs [list $maxConnections $minConnections $unusedTimeout]
$AdminConfig create ConnectionPool $newds $poolAttrs
$AdminConfig save

该脚本执行了三个步骤，首先创建一个名为Oracle10g的jdbc provider，然后在该provider上创建了一个名为dcmp2的数据源，并且配置了一些oracle数据源独有的参数，包括数据库存储的helper类、数据库的url等。需要注意的是我们并没有指定连接数据库的帐号和密码，所以它会以J2C中指定的帐号信息去连接。当然，你也可以在这里单独配置，写到propertySet当中去就可以了。然后我们还修改了连接池的参数，包括最大连接数、最小连接数等。

    然后我们要配置WebSphere MQ队列连接工厂，该连接工厂将指向一个已经配置好的Websphere MQ的队列管理器，它的名称是dcmp2，端口1415，通道名c1。附带说明一下Websphere MQ也有自己的命令行工具，可以用于创建队列管理器、本地队列等。脚本cf.jacl:

#指定cell
set myCell zxhNode01Cell
#指定要配置的node
set myNode zxhNode01
set jmsp [$AdminConfig getid "/Cell:$myCell/Node:$myNode/JMSProvider:WebSphere MQ JMS Provider/"]
$AdminConfig attributes MQQueueConnectionFactory
set name [list name cf]
set jndi [list jndiName mq/cf]
set description [list description 描述信息]
set transportType [list transportType CLIENT]
set queueManager [list queueManager dcmp2]
set ccsid [list CCSID 1381]
set host [list host 192.168.0.10]
set port [list port 1415]
set channel [list channel c1]
set xa [list XAEnabled true]
set mqqcfAttrs [list $name $jndi $description $transportType $queueManager $ccsid $host $port $channel $xa]
set template [lindex [$AdminConfig listTemplates MQQueueConnectionFactory] 0]
$AdminConfig createUsingTemplate MQQueueConnectionFactory $jmsp $mqqcfAttrs $template
$AdminConfig save

    上述脚本建立了连接工厂，而且特别指定它要支持分布式事务（二阶段提交协议）。

    现在可以在这个工厂内创建队列了，脚本queue.jacl:

#指定cell
set myCell zxhNode01Cell
#指定要配置的node
set myNode zxhNode01
set jmsp [$AdminConfig getid "/Cell:$myCell/Node:$myNode/JMSProvider:WebSphere MQ JMS Provider/"]
$AdminConfig attributes MQQueue
set name [list name test]
set jndi [list jndiName mq/test]
set baseQueue [list baseQueueName test]
set target [list targetClient MQ]
set baseManager [list baseQueueManagerName dcmp2]
set mqqAttrs [list $name $jndi $baseQueue $target $baseManager]
set template [lindex [$AdminConfig listTemplates MQQueue] 0]
$AdminConfig createUsingTemplate MQQueue $jmsp $mqqAttrs $template
$AdminConfig save

    该脚本创建了一个jndi名为mq/test的队列，并且指定了它映射的WMQ本地队列是test，也指定了它映射的WMQ的队列管理器名称，这是可选的，如果不写的话，它会采用队列连接工厂的设置。需要特别说明的是，我们指定了目标客户机是MQ（它的默认值是JMS），二者的区别在于，如果是JMS的话，那么队列上保存的将是Java对象，即使你发送的是TextMessage，保存的也是一个java String对象。如果是MQ的话，保存的就是纯文本。

    假设我们的应用中会有一个消息bean监听mq/test队列，那么我们就需要建立对应的消息侦听器端口(listening port)。脚本listener.jacl:

#指定cell
set myCell zxhNode01Cell
#指定要配置的node
set myNode zxhNode01
set myServer server1
set server [$AdminConfig getid /Cell:$myCell/Node:$myNode/Server:$myServer/]
set mls [$AdminConfig list MessageListenerService $server]
set new [$AdminConfig create ListenerPort $mls {{name test}{destinationJNDIName mq/test}{connectionFactoryJNDIName mq/cf}}]
$AdminConfig create StateManageable $new {{initialState START}}
$AdminConfig save

    该脚本指定了侦听器端口的名称，它对应的队列的jndi名，它对应的连接工厂的jndi名。

    资源建立完成，现在部署我们的应用程序，脚本deploy.jacl:

set myCell zxhNode02Cell
set myNode zxhNode02
set myServer server1
$AdminApp install "E:/DCMP2.0/code/MyApp.ear"
$AdminConfig save
set appManager [$AdminControl queryNames cell=$myCell,node=$myNode,type=ApplicationManager,process=$myServer,*]
$AdminControl invoke $appManager startApplication MyApp  

    该脚本部署了我们自己的应用程序并且启动它，基本的部署工作至此完成。上述脚本在WAS 6.0 Net Deploy和WAS6.0 Express两个版本上测试通过。